One Percent A Week: A High-Probability Weekly Trading Strategy For TQQQ

Uncategorized

AIQ code based on Dion Kurczek’s article in March 2026 Stocks & Commodities, “One Percent A Week: A High-Probability Weekly Trading Strategy For TQQQ,” for trading TQQQ is provided in the code file below.

Here’s a look at developing a mean-reversion trading strategy with a minimal number of rules, low time commitment, and a consistent weekly profit target. It could be used by systematic traders and discretionary traders alike. Each rule exists to serve one overarching purpose: capture a 1% gain on TQQQ once per week, on average, without excessive drawdowns or overtrading.

Note that the code provided does not implement the breakeven exit, so once a trade is entered, it is held until it hits the profit target or Friday’s close if the profit target is never hit.

! One Percent A Week (TQQQ)
! Author: Dion KUrczek, TASC March 2026
! Coded by Richard Denning, 1/16/26

!*********BREAK EVEN EXIT NOT IMPLEMENTED*********

! Abbreviations:
O is [open].
L is [low].
H is [high].
C is [close].
OSD is offsettodate(month(),day(),year()).

! Return values for DayOfWeek() function:
Mon if DayOfWeek()  = 0.   
Tues if DayOfWeek()  = 1.
Wed if DayOfWeek()  = 2.
Thur if DayOfWeek()  = 3.
Fri if DayOfWeek()  = 4.   

! Get the open on Monday:
Mon_os is scanany( DayOfWeek()  = 0, 5) then OSD.
O_Mon is valresult(O,^Mon_os).

! Get the close on Friday:
Fri_os is scanany( DayOfWeek()   = 4, 5) then OSD.
C_Fri is valresult(C, ^Fri_os).

! Limit and profit targets:
LimEnt is O_Mon * 0.99.    ! Enter at Limit
PT is LimEnt * 1.01.           ! Exit at profit target

ExitPrice is iff(Mon and H>=PT,PT,
	iff(Tues and H>=PT,PT,
	iff(Wed and H>=PT,PT,
	iff(Thur and H>=PT,PT,
	iff(Fri and H>=PT,PT,^C_Fri))))).

CountEntries is countof(L <= LimEnt, DayOfWeek() + 1). 
CountExits is countof(H >= PT, DayOfWeek()  + 1).

 ! Limit trades to one per week:
Buy if L <= LimEnt and CountEntries = 1 and CountExits <= 1. 

!Exit at profit target or Friday's close:
Sell if H >= PT or DayOfWeek()=4.

ShowValues if 1.

—Richard Denning
rdencpa@gmail.com
for AIQ Systems